@echo off & color & cls
 set hlaska=Test pripojeni na net
 (set LAN=192.168.1.1)    & REM # ip routeru
 (set WAN=0.0.0.0)        & REM # wan ip, u dhcp 0.0.0.0 nebo pouzit ddns 
 (set GTW=44.33.22.1)     & REM # isp brana
 (set DNS1=40.30.20.11)   & REM # isp dns1
 (set DNS2=40.30.22.12)   & REM # isp dns2
 (set ISP=44.33.32.31)    & REM # isp dhcp server
 (set IPW=94.74.192.133)  & REM # isp web ip
 (set WWW=www.muj_isp.cz) & REM # isp web
 (set hot=Hotline: 609 609 609 po-pa do 19h, so 11h)
 (set log=%userprofile%\Plocha\%hlaska%.log) & REM # log
 echo # err_log viz: "%log%"
 title %hlaska%, %date:~-10% %time:~0,5%

:PC
 ipconfig | find "Adresa"
  if errorlevel 1 ipconfig | find "Address"
:LAN
 echo. & echo ROUTER
 ping -n 1 %LAN% | find "TTL="
  if errorlevel 1 echo - chyba %LAN%: domaci router nejde, zastrc kabel ... && pause && goto LAN
:WAN
 REM # DHCP 0.0.0.0 se preskoci, nebo DDNS
 echo %WAN% | find "0.0" >nul
  if not errorlevel 1 goto GTW
 echo. & echo BYT
 ping -n 1 %WAN% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %BYT%: domaci router nema WAN IP z kabelovky && goto ERR
:GTW
 echo. & echo ISP gateway
 ping -n 1 %GTW% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %GTW%: pripojeni ISP z baraku nedostupne - jistic? && goto ERR
:DNS1
 echo. & echo DNS1
 ping -n 1 %DNS1% | find "TTL="
  if errorlevel 1 (goto DNS2) else (goto ISP)
:DNS2
 echo. & echo DNS2
 ping -n 1 %DNS2% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %DNS1%: DNS providera je nedostupne && goto ERR
:ISP
 echo. & echo ISP DHCP
 ping -n 1 %ISP% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %ISP%: sit ISP nefunguje && goto ERR
:IPW
 echo. & echo IP webu ISP
 ping -n 1 %IPW% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %IPW%: ISP nema spojeni na net && goto ERR
:WWW
 echo. & echo WWW %WWW%
 ping -n 1 %WWW% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %WWW%: ISP ma net, nefunguje preklad DNS && goto ERR
 color 20 & echo. & echo *** vsecko funguje *** & echo. & goto TRAC

:ERR
 echo. & echo - %date%, %time:~0,8% > "%err%" && echo %hlaska% >> "%log%" && echo. >> "%log%"
 color 47 & type "%log%"
 echo - tracert:
 tracert %ISP% | find " "
 echo. & echo %hot% & echo.
 pause && goto END

:TRAC
 tracert %WWW% | find " "
 ping -n 3 127.0.0.1 >nul
:END