@echo off && REM -- uvadet absolutni cesty bez pismene flashky
 echo *************************************************************************
 echo *  INSTALACNI BATKA PRO NOVE TESTERY. Start z flashky pres Autorun nebo *
 echo *  spustit XPinstal.bat. Opakovany start zastupcem v Allusersprofile.   *
 echo *  verze 4, 22.12.2010                             brum brum, tel.1234  *
 color 70
 chcp 1250 && mode con: lines=50 && title %0 [%username%]
 set log=c:\tmp\xp.log
 set reg=XP.reg
 set admin=Administrator
 set usr2=lopata
 set AR=_
 set filemng=Master Commander
 if not exist c:\tmp\*.* md c:\tmp
 if exist %log% goto 0_VYBER
 echo ********** && echo # Start z flashky
 echo %computername% %date% %time:~0,5% > %log%
 goto 1_USB_INSTAL
:0_VYBER
 type %log% && REM -- Kontrola uzivatelu a prubeh instalace
 if exist C:\WINDOWS\se_pracuje_red.bmp goto F3
 echo ********** && echo # Nastavovac musi byt %admin%
 if /i %username%==%admin% (goto 2_ADMIN_SET) else goto ODHLASENI
:F3
 REM -- Usr2 uz muze existovat, nema cenu ho testovat
 find "#3" %log%
 if not errorlevel 1 goto F6
 if /i %username%==%admin% goto 3_MOTIVY
 echo ********** && echo # Tunit vzhled a zalozit 2.user muze jen %admin%
 goto ODHLASENI
:F6
 REM -- Test domeny
 net view | find /i "\\domena"
 if not errorlevel 1 goto F8
 echo ********** && echo # Copy profile do Default user dela %usr2%
 if /i %username%==%usr2% goto 6_LOGIN2
 set admin=%usr2% && goto ODHLASENI
:F8
 echo # Tester je v domene
 if /i %username%==%admin% goto 8_UKLID
 goto ODHLASENI

REM ==== Kdokoli 1.start: zajistit Autostart batky. Kopirovani a instalace.
:1_USB_INSTAL
 set ph=#1 Instalace softu z flashky - kdokoli
 color 70 && title %ph% [%username%]
 if not exist \TE\*.* goto AR_VERZE
:COPY
 echo ********** && echo # Kopirovani pomocnych souboru z flashky
 copy %0 c:\tmp
 \TE\shortcut.exe /t:c:\tmp\%~nx0 /f:"%allusersprofile%\Start Menu\Programs\Startup\XPinstal.lnk" /a:c
 copy \TE\%reg% c:\tmp /y
 copy \TE\venturi.sys c:\tmp && copy \TE\venturi.sys c:\
 copy \TE\se_pracuje_red.bmp C:\tmp
 copy \TE\SysSpec.exe %windir%
:MSNET20
 echo ********** && echo # Instalace MS .Net 2.0 trva asi 2 minuty
 copy \TE\MSNet\NetFx20SP1_x86.exe C:\tmp
 C:\tmp\NetFx20SP1_x86.exe /qb /norestart
:FILEMANAGER
 echo ********** && echo # Spravce souboru %filemng% .............. (._.')
 xcopy "\TE\%filemng%" "C:\Program Files\%filemng%" /e /h /i /q
 regedit /s "c:\Program Files\%filemng%\%filemng%.reg"
 copy "\TE\%filemng%\%filemng%.lnk" "%allusersprofile%\Desktop"
:NERO
 echo ********** && echo # Nero: InCD ven, kill Nindex, NeroScout ...... (._.')
 set comNero=
 if exist "%commonprogramfiles%\Ahead\*.*" set comNero=%commonprogramfiles%\Ahead
 if exist "%commonprogramfiles%\Nero\*.*" set comNero=%commonprogramfiles%\Nero
 if "%comNero%"="" goto STARTER
REM -- if exist %windir%\system32\drivers\InCDfs.sys "%windir%\NuNInst.exe /UNINSTALL"
 reg delete HKLM\Software\Microsoft\Windows\CurrentVersion\Run /v NMBgMonitor /f
 net stop NMIndexingService
 regsvr32 /u "%comNero%\Lib\MediaLibraryNSE.dll"
:STARTER
 echo ********** && echo # Starter (autoruns a procesy)
 xcopy \TE\!Starter "C:\Program Files\!Starter" /e /h /i /q
:VNC
 echo ********** && echo # VNC: zatrhnout Startskupinu a zastupce, heslo
 \TE\vnc-4_1_2-x86_win32.exe
 move "%userprofile%\Desktop\VNC*.lnk" "%allusersprofile%\Desktop"
:AREADER
 echo ********** && echo # hledani verze AReaderu pro vytuneni
 if exist "C:\Program Files\Adobe\*.*" goto AR_VERZE
 copy \TE\PDF\AdbeRdr710_en_US.exe c:\tmp && c:\tmp\AdbeRdr710_en_US.exe
REM copy \TE\PDF\SumatraPDF-101-install.exe c:\tmp && c:\tmp\SumatraPDF-101-install.exe
REM goto COMTROL
:AR_VERZE
 dir /b "C:\Program Files\Adobe\"
 if exist "C:\Program Files\Adobe\Acrobat 6.0\*.*" set AR=6
 if exist "C:\Program Files\Adobe\Acrobat 7.0\*.*" set AR=7
 if exist "C:\Program Files\Adobe\Reader 8.0\*.*" set AR=8
 if exist "C:\Program Files\Adobe\Reader 9.0\*.*" set AR=9
 copy \TE\PDF\AcrobatReader%AR%.reg c:\tmp
 if /i not %username%==%admin% ren c:\tmp\AcrobatReader%AR%.reg c:\tmp\AcrobatReader_.reg 
:COMTROL
 echo ********** && echo # kopirovani driveru RocketPort PCI, z CD rev.H 2009
 if not exist c:\comtrol\*.* xcopy \TE\comtrol c:\comtrol /c /i /q
 copy \TE\devcon.exe %windir%
REM -- log
 echo %time:~0,5%, %username%, %ph% >> %log%
 if /i %username%==%admin% goto 2_ADMIN_SET
 echo ********** && echo # Instalace OK, ale nastaveni jen %admin%
 goto ODHLASENI

REM ==== Admin: nastavit prostredi
:2_ADMIN_SET
 set ph=#2 Vzorove nastaveni Administrator
 color 30 && title %ph% [%username%]
REM echo %username% %date% %time:~0,5% >> c:\tmp\%username%.%ph%
 echo ********** && echo # Import hustonastaveni registru
 REM V reg souboru HKCU misto HKLM kvuli prepsani uz existujiciho Admina
 regedit /s c:\tmp\%reg%
 if errorlevel 1 color 40 && set hlaska=Chyba importu do registru && goto ERROR
:AR_ADMIN
 echo ********** && echo # Import nastaveni pro AReader
 if exist c:\tmp\AcrobatReader%AR%.reg regedit /s c:\tmp\AcrobatReader%AR%.reg
:DEVMGMT
 echo ********** && echo # Spravce zarizeni: ovladace "%computername%" OK?
 echo # je osazen RocketPort? Zavrit spravce zarizeni pro pokracovani [X]
 reg query "HKLM\SYSTEM\CurrentControlSet\Enum\PCI\VEN_11FE&DEV_0005&SUBSYS_00000000&REV_04"
 C:\WINDOWS\system32\devmgmt.msc
 echo ********** && echo # Zakazat rezim spanku
 powercfg /hibernate off
:DISPLAY
 echo ********** && echo # Klavesove zkratky grafiky zruseny v registrech
REM C:\WINDOWS\system32\igfxcfg.exe
:IKONY
 echo ********** && echo # Mazani zastupcu a pozadi
 del /s /f /q "%userprofile%\Favorites\*.url"
 rd /s /q "C:\Documents and Settings\Default User\Favorites"
 md "C:\Documents and Settings\Default User\Favorites"
 del /f /q "%userprofile%\Start Menu\Programs\Outlook Express.lnk"
 rd /s /q "%allusersprofile%\Start Menu\Programs\Games"
 del /f /q "%allusersprofile%\Start Menu\*.lnk"
 del /f "%allusersprofile%\Start Menu\Programs\MSN.lnk"
 del /f /q "%allusersprofile%\Start Menu\Programs\Startup\Adobe*"
 del /f /q "%allusersprofile%\Desktop\Adobe*"
 del /f "%allusersprofile%\Desktop\Windows Media Player.lnk"
 del /f "C:\Documents and Settings\Default User\SendTo\Mail Recipient.MAPIMail"
 del /f "%userprofile%\SendTo\Mail Recipient.MAPIMail"
 del /f "%userprofile%\SendTo\My Documents.mydocs"
 del "%AllUsersProfile%\Start Menu\Windows Update.lnk"
 del "%AllUsersProfile%\Start Menu\Set Program Access and Defaults.lnk"
 del "%AllUsersProfile%\Start Menu\Windows Catalog.lnk"
 echo # Wallpaper
 del /f /q "C:\WINDOWS\Web\Wallpaper\*.*"
 del /q "C:\WINDOWS\*.bmp"
 move C:\tmp\se_pracuje_red.bmp C:\WINDOWS\
:REGISTRY
 echo ********** && echo # Specificke nastaveni jen pro testery, v XP.reg zaremovano
 echo - klavesnice ve Win: 0409=us (10405=QWERTY, 0405=cz)
 reg add "HKCU\Control Panel\International" /v Locale /d 00000409 /f
 echo - IE home
 reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /v "Start Page" /d "https://ledni.obora.cz/" /f
 echo - zakaz IE proxy
 reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 0 /f
 echo - vypnuti internetoveho casu
 reg add HKLM\SYSTEM\CurrentControlSet\Services\W32Time\Parameters /v Type /t REG_SZ /d NoSync /f
 echo - if WINS server available, NetBT uses H-node
 reg add HKLM\SYSTEM\CurrentControlSet\Services\NetBT\Parameters /v DhcpNodeType /t REG_DWORD /d 8 /f
 echo - AutoEnrollment: Do not enroll certificates automatically
 reg add HKLM\SOFTWARE\Policies\Microsoft\Cryptography\AutoEnrollment /v AEPolicy /t REG_DWORD /d 8000 /f
 echo - Filemanager nastaveni
 regedit /s "c:\Program Files\%filemng%\%filemng%.reg"
 echo # Activate registry changes in HKCU without logging off
 rundll32.exe user32.dll,UpdatePerUserSystemParameters ,1 ,True
 C:\WINDOWS\system32\gpupdate.exe /wait:-1
:SERVICES
 echo ********** && echo # Zakazat sluzby - jen testery na hale (az po Restartu)
 reg add HKLM\SYSTEM\CurrentControlSet\Services\WZCSVC /v Start /t REG_DWORD /d 4 /f
 reg add HKLM\SYSTEM\CurrentControlSet\Services\WebClient /v Start /t REG_DWORD /d 4 /f
 reg add HKLM\SYSTEM\CurrentControlSet\Services\FastUserSwitchingCompatibility /v Start /t REG_DWORD /d 4 /f
 reg add HKLM\SYSTEM\CurrentControlSet\Services\RemoteRegistry /v Start /t REG_DWORD /d 4 /f
 reg add HKLM\SYSTEM\CurrentControlSet\Services\wuauserv /v Start /t REG_DWORD /d 4 /f
 echo ********** && echo # zrusit Messenger
 RunDll32 advpack.dll,LaunchINFSection %windir%\INF\msmsgs.inf,BLC.Remove
:TCPIP
 echo ********** && echo # Nastaveni nazvu PC a IP pro "%computername%"
 echo # Nachystat sitovy kabel. Pri zmene nazvu PC NEpotvrzovat restart [OK]
 Control sysdm.cpl,,1
 echo # nastaveni IP: 10.10.x.y, maska: 255.255.252.0, brana: - 
 echo # DNS: 10.10.10.10, domain prefix: fs.cz.conti.de, WINS: 10.10.10.10
 echo Pokud je 2. sitovka, ma nastaveni: 172.16.16.21 / 255.255.255.0
 echo ********** && echo # Kontrola TCP/IP
 ipconfig -all
 C:\WINDOWS\system32\ncpa.cpl
 echo ********** && echo # Vypne se firewall: sitovy kabel zasunout!
 netsh firewall set opmode disable
 if errorlevel 1 echo Nezdarilo se, zakazat fw (ICS=sluzba SharedAccess)
:BIOS
 set hlaska=# v BIOSu - Power Management - "PowerOn after PwrFail: Off"
:DISKY
 echo ********** && echo # Sprava disku - opravit pismeno CD na O: [X]
 net share | find /i "D:"
 if errorlevel 1 echo # Neni vytvorene D:, pri Restartu spravit Disk Directorem
 diskmgmt.msc
REM -- log
 echo %time:~0,5%, %username%, %ph% >> %log%
 title Nove prihlaseni jako %Admin%. Behem vypnuti lze osadit RocketPort.
 goto RESTART

REM ==== az po 1.restartu, provadi jen Admin
:3_MOTIVY
 set ph=#3 Rucni nastaveni Classic vzhledu
 color 30 && title %ph% [%username%] && echo ********** Je NUTNO naklikat:
 echo 1) Pravym mysem dole Start_lista - vlastnosti: Odemknout, Neskryvat ikony,
 echo    Nabidka=Classic, zakaz Personalized menus, zakaz expand Control panel
 RunDLL32.EXE shell32.dll,Options_RunDLL 1
 echo 2) Theme=Classic, plocha bez wallp., dole ikony: Tento PC, necistit plochu
 echo    ScrSaver - None, set: 16-bit colors [X pokracuje dal]
 control desktop
 echo 3) Vlastnosti TentoPC: Advanced - Performance - Visual Effect=3.Best Perf.
 Control sysdm.cpl,,3
 echo ********** && echo # zkontrolovat vsechna nastaveni oken
 control folders
 echo ********** && echo # Jazyk: klavesnice US, prostredi US, lokalita CZ
 Control intl.cpl,,0
:DATUM
 echo ********** && echo # Datum a cas: %date%, %time% [OK pokracovat]
 Control timedate.cpl
:NET
 echo ********** && echo # Test site, lze mapovani serveru a VNC [X pokracovat]
 ping -n 1 10.10.10.10
 if errorlevel 1 echo # Nejde sit! && pause
REM net use z: \\10.10.10.6\venturi /user:TESTERS\operator /persistent:no
 "C:\Program Files\RealVNC\VNC4\vncviewer.exe"
:IE
 echo ********** && echo # IE rozvrzeni toolbaru, kontrola nastaveni [X]
 rem C:\WINDOWS\system32\inetcpl.cpl
 "C:\Program Files\Internet Explorer\iexplore.exe"
:ZVUK
 echo ********** && echo # Vybrat "No sound" schema
 Control mmsys.cpl,,1
REM -- log
 echo %time:~0,5%, %username%, %ph% >> %log% && echo.

:4_USERS
 set ph=#4 Zalozeni uctu %usr2% a test aktivace Win
 color 30 && title %ph% [%username%]
 net user %usr2%
 if not errorlevel 1 goto AKTIVACE
 net user %usr2% /add /active:yes /passwordchg:no /passwordreq:no /expires:never
 net localgroup Administrators %usr2% /add
 net localgroup Users %usr2% /delete
 net user %usr2%
:AKTIVACE
 echo ********** && echo # Test aktivace Windows .................. (._.')
 tasklist /svc | find "wpabaln.exe"
 if errorlevel 1 goto THANKS
 set key=Autocont ProductKey: 'xxxx-xxxx-xxxx'
 color 17 && echo # zaregistrovat %key% && title #4. %key%
 echo Vygenerovat kod a do sluzebniho mobilu na 225 990 844 (home user) zadat 
 echo 9x 6-mistnou skupinu. Pres "1" poslou v SMS 7 skupin aktivacniho kodu.
 echo -- && echo Nebo pouzit image stejneho hw z 10.10.11.11\backup$
 %windir%\system32\oobe\msoobe.exe /a
:THANKS
REM -- log
 echo %time:~0,5%, %username%, %ph% >> %log% && echo.

:5_KONTROLA
 set ph=#5 doladit Admina na vzorovy profil 
 color 30 && title %ph% [%username%]
 echo ********** && echo # Abecedni srovnani nabidky Start
 reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MenuOrder\Start Menu\Programs" /v Order /f
 reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MenuOrder" /v Order /f
 echo ********** && echo # kontrola Local policies v gpedit (Agilent, Advantech)
 gpedit.msc
 echo ********** && echo # kontrola instalovanych aplikaci
 Control appwiz.cpl
REM ..................................................... zvazit co jeste chybi
 echo ********** && echo # Poradek v procesech po startu musi bejt [X]
 "C:\Program Files\!Starter\Starter.exe"
 echo ********** && echo # kontrola D:
 net share | find /i "D:"
 if errorlevel 1 set hlaska=# Restart: rozdelit disk Acronis Disk Directorem
 echo ********** && echo # Vzorove nastaveni OK. Po restartu prihlasit '%usr2%'!
 title # po Restartu prihlasit jako %usr2%. Behem vypnuti lze osadit RocketPort.
REM -- log
 echo %time:~0,5%, %username%, %ph% >> %log%
 goto RESTART

REM ==== prihlaseni jako Usr2 az po 2.restartu, teprv si vytvori profil
:6_LOGIN2
 set ph=#6 Kopirovat vzorovy profil %admin% do Default User
 color 57 && title %ph% [%username%]
 echo ********** && echo # V c:\venturi.sys je cesta k \Default User
rem start C:\PROGRA~1\MASTER~1\MASTER~1.EXE ..................................?
rem cmd /c "C:\Program Files\%filemng%\%filemng%.exe"
 echo - do schranky: C:\Documents and Settings\Default User
 echo - prostredni Profily uzivatelu: zkopirovat %admin% do Default User
 control sysdm.cpl,,3
:SECURITY
 echo ********** && echo # Kontrola v Security center vypnuta - (3x vlevo) [OK]
 C:\WINDOWS\system32\wscui.cpl
REM -- log
 echo %time:~0,5%, %username%, %ph% >> %log%

:7_DOMENA
 set ph=#7 pridej PC do domeny TESTERS!
 color 57 && title %ph% [%username%]
REM -- log
 echo %time:~0,5%, %username%, %ph%>> %log%
 echo ********** && echo # Rucne do domeny [OK = Restart!], pak lokalni Admin
 set hlaska=# Uz je rozdeleny disk? Byl osazen pripadny RocketPort?
 control sysdm.cpl,,1
 goto RESTART

REM ==== po Restartu jako lokalni Admin, konecne doladeni pro domenu
:8_UKLID
 set ph=#8 uklid pred prvnim prihlasenim pod domenovym uctem
 color 20 && title %ph% [%username%]
 echo ********** && echo # odstraneni CAD pro prihlaseni && REM control userpasswords2
 reg add "HKLM\Software\Microsoft\Windows NT\CurrentVersion\Winlogon" /v "DisableCAD" /t REG_DWORD /d 1 /f
 echo ********** && echo # Pridat TESTERS\Testers group do Administrators
 net localgroup Administrators "TESTERS\Testers group" /add
 echo ********** && echo # Zrusit pomocneho uzivatele %usr2% a profil [OK]
 net user %usr2% /delete
 Control sysdm.cpl,,3
 echo ********** && echo # Heslo pro admina
 set /p local_pswd=zadej nove heslo pro %admin%:
 net user %admin% %local_pswd%
 net accounts /maxpwage:unlimited
:BARVY_ADM
 echo ********** && echo # Admin color scheme:Brick, pozadi: se_pracuje_red.bmp
 C:\WINDOWS\system32\control color
 reg add "HKCU\Control Panel\Desktop" /v Wallpaper /t REG_SZ /d C:\WINDOWS\se_pracuje_red.bmp /f 
:KONEC_AUTORUN
 echo ********** && echo # Smazani zastupce batky z Allusers-Start Menu
 del "%allusersprofile%\Start Menu\Programs\Startup\XPinstal.lnk"
:TEST_COMTROL
 echo ********** && echo # test na RocketPort [zavrit OK]
 echo # MS driver:'VEN_11FE+DEV_0005+SUBSYS_00000000+REV_04', OK = C:\Comtrol
 echo - fyzicky ve slotu: && devcon.exe status PCI\VEN_11FE
 echo - kdyz je zaznam v registrech, nabidne ovladac [X]
 reg query HKLM\SYSTEM\CurrentControlSet\Enum\PCI\ | find "VEN_11FE"
 if not errorlevel 1 C:\WINDOWS\system32\devmgmt.msc
:ENDLOCAL
 echo ********** && set admin = TESTERS\root
 echo # Konec vsech nastaveni :-) Prihlasit se domenovym uctem %admin%
 echo # Doporucena zaloha zadomenovanych Windows s Acronis TI 2010
 echo # pro Tester2 prejmenovat C:\venturi.sys
REM -- log
 echo %time:~0,5%, %username%, %ph% >> %log% && echo.
 goto ODHLASENI

:ERROR
 color 40 && echo %hlaska% && pause && goto :EOF

:ODHLASENI
 echo ! Uzivatel %username% - odhlasit a prihlasit jako %admin% !
 color d0 && title %ph%
 echo (>”"<) && echo ( ‘.’) && echo (“)(“) && pause
 shutdown -l -f -t 0
:RESTART
 color c0 && echo ! Pro vynuceni zmen v registrech se vyvola RESTART ! 
 echo %hlaska%
 echo (\__/) && echo (='.'=) && echo (")_(") && pause 
 shutdown -r -f -t 0

:END
 echo ********** && echo # Koncit restartem ... za par sekund
 shutdown -r -f -t 5

goto :EOF

REM -- Tento PC - vlastnosti
 C:\WINDOWS\system32\sysdm.cpl
REM -- Prejmenovat PC
 control sysdm.cpl,,1
REM -- nahore Vykon, uprostred Profily uzivatelu
 control sysdm.cpl,,3
REM -- Sprava disku
 C:\WINDOWS\system32\diskmgmt.msc
REM -- Zasady skupin
 C:\WINDOWS\system32\gpedit.msc
REM -- Spravce zarizeni
 C:\WINDOWS\system32\devmgmt.msc
REM -- Kontrola nainstalovanych aplikaci
 C:\WINDOWS\system32\appwiz.cpl
REM -- Prohlizec udalosti
 C:\WINDOWS\system32\eventvwr.msc
REM -- Naklikat noveho uzivatele, Mistni uzivatele a skupiny
 C:\WINDOWS\system32\nusrmgr.cpl
 C:\WINDOWS\system32\lusrmgr.msc
REM -- Security center
 C:\WINDOWS\system32\wscui.cpl
 RunDLL32.EXE shell32.dll,Control_RunDLL wscui.cpl
REM -- barevne schema
 C:\WINDOWS\system32\control.exe color
REM -- Display background
 RunDLL32.EXE shell32.dll,Control_RunDLL desk.cpl,,0
REM -- Map Network Drive wizard
 RUNDLL32.EXE shell32.dll,SHHelpShortcuts_RunDLL Connect
REM -- ShortCut
 rundll32.exe AppWiz.Cpl,NewLinkHere c:\test.txt
REM -- Activate registry changes in HKEY_CURRENT_USER without logging off:
 RUNDLL32.EXE USER32.DLL,UpdatePerUserSystemParameters ,1 ,True

REM -- historie verzi:
REM 1. - "beta" s chybami, nejdriv nastaveni pak instalace, batka 7kB, reg 3kB
REM 2. - Autostart pres Allusersprofile, zacne instalaci, 13kB, reg 6kB
REM 3. - kopie profilu, opravy, domenovi uzivatele, .Net, 16kB, reg 7kB
REM 4. - opravy, zpresneni hlaseni a vyzev, RocketPort, 17kB, reg 8kB

:EOF