Soft na hromadné přejmenování souborů v adresáři podle názvu adresáře?

Buď si na to napiš VBS skriptík (IMHO to je tak na 10 řádek), nebo to můžeš dělat v TC - ctrl+M, nadefinuješ si nové jméno (něco jako [P][C] a počet číslic nastavíš např. na 4, v zápise např. takto: [P][C1+1:4]) a celé si to pojmenuješ a uložíš, abys to nemusel nastavovat pokaždé.

no, to není úplně ono...

v podstatě je to stejný postup, který dosud používám (Name It), jenže to musím každý adresář zvlášť, lezt do něj atd., a to je na dlouho a opruz...

jestli to máš v jednom hlavním adresáři, tak ti na to odpoledne napíšu to vbs-ko

no, to mám, to bych ti byl vděčnej

mimochodem, VBS mi nic neříká, teda vím, co to je, ale tím to končí...

Tak tady to je:

 Dim fso, f, sf, sfl, folder, file, filelist, counter, warning, stary, novy
  path = InputBox("Zadejte cestu k nadřazenému adresáři ve kterém se nachází adresáøe s obrázky")
  warning = MsgBox("Budou přejmenovány soubory v podadresářích tohoto adresáře: " & path & ". Je to správně?", 276, "Poslední záchrana") 
  if warning = 6 then
  	Set fso = CreateObject("Scripting.FileSystemObject")
  	Set f = fso.GetFolder(path)
  	Set sf = f.SubFolders
  	For Each folder in sf
		counter = 1
		Set sfl = fso.GetFolder(folder)
		set filelist = sfl.Files
		Wscript.echo " "
		Wscript.echo "Adresář " & folder
		Wscript.echo "číslo - starý název - nový název"
		Wscript.echo "==============================================================================="
		For Each file in filelist
			stary = file
			novy = folder & "\" & folder.Name & Right("0000" & CStr(counter),4) & "." & Right(stary,3)
			fso.MoveFile stary, novy
			wscript.echo counter & " - " & stary & " - " & novy
			counter = counter + 1
		next

	  next
 	Wscript.echo "Akce provedena!"
  Else
  	Wscript.echo "Akce byla zrušena!"
 	
  end if

ulož si to jako "něco.vbs" a doporučuju spouštět pomocí příkazu cscript něco.vbs v konzoli CMD.

Chyby které jsem neodladil: Čas od času se mi stane, že první přejmenování (pro mě nepochopitelně) vezme při volání metody sfl.Files (tj. při načítání jmen souborů) i sobory, které "teprve budou" - jak kdyby během vnitřní smyčkou ještě jednou aktualizoval -> z toho plyne, že se může stát, že číslování nepůjde od 0001, ale od vyššího čísla. Nicméně druhé spuštění skriptu proběhne už ok. Jsem zmaten, vysvětlí mi to někdo? (Přece jen nejsem VBS guru ) Ještě mě napadá přepsat to pomocí WMI, ale to se mi už nechce

Možné úpravy: Pokud se z obou cyklů vyhážou všechny Wscript.echo výpisy do konzoly, je možné pohodlně spouštět skript pomocí wscript (tj. poklikáním na ikonku), ale pak není žádný záznam o činnosti skriptu. Dále je možno změnit počet nul v číslování - postačí změnit poslední číslovku ve funci Right("0000" & CStr(counter),4) na požadovanou hodnotu (nyní jsou 4)

Koukám, že tady roste konkurence JaFimu, který má patent na psaní utilit na požádání...

JaFi musí opravovať chyby v PSPade a teraz na to nemá čas. Však Intex? Ozaj a čo je s JaFim?

Chyba byla odhalena Nechtěně jsem nedodal v jedné části odpovídající property, teď už by to mělo být ok.

 Dim fso, f, sf, sfl, folder, file, filelist, counter, warning, stary, novy
  path = InputBox("Zadejte cestu k nadřazenému adresáři ve kterém se nachází adresáře s obrázky")
  warning = MsgBox("Budou přejmenovány soubory v podadresářích tohoto adresáře: " & path & ". Je to správně?", 276, "Poslední záchrana") 
  if warning = 6 then
  	Set fso = CreateObject("Scripting.FileSystemObject")
  	Set f = fso.GetFolder(path)
  	Set sf = f.SubFolders
  	For Each folder in sf
		counter = 1
		Set sfl = fso.GetFolder(folder)
		set filelist = sfl.Files
		Wscript.echo " "
		Wscript.echo "Adresář " & folder
		Wscript.echo "číslo - starý název - nový název"
		Wscript.echo "==============================================================================="
		For Each file in filelist
			stary = file
			novy = folder.path & "\" & folder.Name & Right("0000" & CStr(counter),4) & "." & Right(stary,3)
			fso.MoveFile stary, novy
			wscript.echo counter & " - " & stary & " - " & novy
			counter = counter + 1
		next

	  next
 	Wscript.echo "Akce provedena!"
  Else
  	Wscript.echo "Akce byla zrušena!"
 	
  end if

super, dostal jsem se k tomu až teď, ale funguje to krásně, díky moc

Taky děkuju, ten script jsem rovněž využil. Jen, možná kvůli většímu počtu přejmenovaných .jpg, se přípona asi u 200 z 1100 .jpg změnila v .peg. Při dalším pokusu o přejmenování stejné sady fotek se počet chybných snížil asi na 50. Taky .peg. Je to zvláštní a mám hledat chybu v hardware, že tu operaci nestíhal, nebo je to normální a je to tím velkým množstvím?
CPU 2.26 GHz, RAM 512 MB. Docela mě to zajímá, ale k netu se dostanu až odpoledne, tak sorry, že třeba hned nebudu reagovat.

Ten skript rozhodně nemá vliv na pojmenování přípony. Já jsem zatím zkusil přejmenovat adresář jen s 250 soubory, různé přípony, a vše proběhlo OK.

edit: tak jo, má to vliv i na ty přípony - např. soubor image.js to přejmenovalo na image..js
každopádně, tak jak to je mi to vyhovuje ještě jednou díky

ano, skript počítá jen s třípísmennými koncovkami (a bere za novou koncovku souborů poslední 3 písmenka z původního souboru; tj. např. z obrázek.jpeg bude právě ten image0001.peg). Bohužel VBS bere filename jako kompletní, nerozlišuje koncovku a bylo by nutné dopsat další kód, který by to ošetřoval, což mi připadlo jako zbytečné..

Kdybyste to chtěli dodělat, tak bych o tom uvažoval

nedalo mi to a upravil/opravil jsem to

Dim fso, f, sf, sfl, folder, file, filelist, counter, warning, stary, novy, koncovka
  path = InputBox("Zadejte cestu k nadřazenému adresáři ve kterém se nachází adresáře s obrázky")
  warning = MsgBox("Budou přejmenovány soubory v podadresářích tohoto adresáře: " & path & ". Je to správně?", 276, "Poslední záchrana") 
  if warning = 6 then
  	Set fso = CreateObject("Scripting.FileSystemObject")
  	Set f = fso.GetFolder(path)
  	Set sf = f.SubFolders
  	For Each folder in sf
		counter = 1
		Set sfl = fso.GetFolder(folder)
		set filelist = sfl.Files
		Wscript.echo " "
		Wscript.echo "Adresář " & folder
		Wscript.echo "číslo - starý název - nový název"
		Wscript.echo "==============================================================================="
		For Each file in filelist
			stary = file
			koncovka = Split(file.name, ".", -1, 1)
			novy = folder.path & "\" & folder.Name & Right("0000" & CStr(counter),4) & "." & koncovka(UBound(koncovka))
			fso.MoveFile stary, novy
			wscript.echo counter & " - " & stary & " - " & novy
			counter = counter + 1
		next

	  next
 	Wscript.echo "Akce provedena!"
  Else
  	Wscript.echo "Akce byla zrušena!"
 	
  end if

Díky, hluboká poklona tvým znalostem a ochotě.

ook-eek!

Ha!To delal Polda ze Ctyrlistku!

umi to i acdsee

hmm, a která verze? a můžeš to trochu upřesnit? myslím, že se pleteš...

Ale nie každý bude ACDSee kvôli tomu inštalovať.

jednak instalovat a jednak kupovat

každopádně jsem tuhle funkci v ACDSee nenašel...

Ja síce ACDSee používam, ale žiaľ, je to síce platený program, ale banálnu vec ako prevod obrázku na ikonu mi musí robiť IrfanView. No a čo sa týka kupovania, keby o to išlo, tak by sa dalo nainštalovať a premenovať (ak to naozaj dokáže) a prestať používať, je to totiž trial. Lenže ja som chcel skôr naznačiť to, že načo používať kamión na prevoz stoličky o 200 m.

super diky, i po nekolika letech byl pro me problem sehnat neco co zvladne takovouhle primitivni ulohu. total commander to neumi a zkousel jsem dalsi 3 renamery nez jsem narazil na tohle reseni. dik

Do TC stačí doinstaloval FileX a v hromadném přejmenování je to potom pod tlačítkem [=?] filex - ParentDir.