@echo off & color & cls
 set LAN=ip.adresa.routeru
 set WAN=moje.ip.od.poskytovatele
 set GTW=ip.gateway.poskytovatele
 set DNS1=prvni.dns.poskytovatele
 set DNS2=druhy.dns.poskytovatele
 set ISP=moje.verejna.ip
 set IPW=ip.webu.poskytovatele
 set WWW=www.poskytovatel.cz
 set hot=tel. hotline: 906 609 906, hotline@poskytovatel.cz
 set err=Plocha\isp_err.log
 echo # Test pripojeni na net, err_log viz: "%err%"
:PC
 ipconfig | find "Adresa"
:LAN
 echo. & echo ROUTER
 ping -n 1 %LAN% | find "TTL="
  if errorlevel 1 echo - chyba %LAN%: domaci router nejde, zastrc kabel ... && pause && goto LAN
:WAN
 echo. & echo BYT
 ping -n 1 %WAN% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %BYT%: domaci router je vadny, neni WAN IP && goto ERR
:GTW
 echo. & echo GATEWAY
 ping -n 1 %GTW% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %GTW%: pripojeni ISP z baraku nedostupne - jistic? && goto ERR
:DNS1
 echo. & echo DNS1
 ping -n 1 %DNS1% | find "TTL="
  if errorlevel 1 (goto DNS2) else (goto ISP)
:DNS2
 echo. & echo DNS2
 ping -n 1 %DNS2% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %DNS1%: DNS za gateway providera je nedostupne && goto ERR
:ISP
 echo. & echo ISP
 ping -n 1 %ISP% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %ISP%: sit ISP nefunguje && goto ERR
:IPW
 echo. & echo IP webu ISP
 ping -n 1 %IPW% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %IPW%: ISP nema spojeni na net && goto ERR
:WWW
 echo. & echo WWW
 ping -n 1 %WWW% | find "TTL="
  if errorlevel 1 set hlaska=- chyba %WWW%: ISP ma net, nefunguje preklad DNS && goto ERR
 echo *** vsecko funguje *** & color 20 & goto TRAC
:ERR
 set err=%userprofile%\%err%
 echo - %date%, %time:~0,8% > "%err%" && echo %hlaska% >> "%err%" && echo. >> "%err%"
 color 47 & type "%err%"
 echo - tracert:
 tracert %ISP% | find " "
 echo. & echo %hot% & echo.
 goto END
:TRAC
 tracert %WWW% | find " "
:END
 pause