CMD-pingovani

@ECHO OFF
PING 209.85.238.11 -n 1 | FIND "ms" > NUL
IF NOT ERRORLEVEL 1 ECHO IP 209.85.238.11 ONLINE
IF     ERRORLEVEL 1 ECHO IP 209.85.238.11 OFFLINE
pause

To si už pak rozkopíruješ kolikrát potřebuješ

super, diky moc!

kdyby ty ip byly po sobě, šlo by je naflákat do smyčky:

@echo off & REM *** ping sem, ping tam ***
 set IPmin=1
 set IPmax=254
 set range=192.168.0
 set log=ip.log
goto CYKLUS

:CYKLUS
 for /l %%a in (%IPmin%,1,%IPmax%) do call :PINGU %range%.%%a
goto END

:PINGU
 ping -n 1 %1
  if errorlevel 1 echo %1 je offline >> %log%
 goto :EOF

:END
 arp -a >> %log%
 start "vypis %log%" cmd /k type %log%

řádek "if errorlevel 1 ..." by šel rozšířit:

 if errorlevel 1 (echo %1 je offline >> %log%) else (echo %1 je online >> %log%)

ale přijde mi to zbytečné, když je na konci výpis arp.

tento script je lepsi, protoze nemusim vytvaret seznam IP pro opingovani staci vlastne zadat nahore od/do, ale po spusteni je neprehledny, protoze vypisuje udaje o zaslanych paketech a td. Co je potreba prepsat aby to ukazalo jenom IP a stav online/offline?
diky.

Tak přesměruj výstup příkazu PING do NUL, jako marekdrtic:

 ping -n 1 %1 >nul

jj, uz to jede. diky

@echo off
set od=1
set do=254
set range=192.168.2
goto CYKLUS

:CYKLUS
for /l %%a in (%od%,1,%do%) do call :PINGU %range%.%%a
goto END

:PINGU
ping -n 1 %1 >NUL
IF NOT ERRORLEVEL 1 ECHO %1 online
IF ERRORLEVEL 1 ECHO %1 offline
goto :EOF

:END
pause

Případně místo běžné inkrementální iterace ve for cyklu lze použít zdrojový soubor s IP adresy a iterovat přes něj.

Nechceš zkusit http://www.nirsoft.net/utils/multiple_ping_tool.ht ml ? Připadne mi to pohodlnější.

o existenci techno nastroju vim(ipscan, netscan, angry ip scanner, atd.). Slo mi o pingovani z cmd s vlastnim scriptem.