Excel - Jak vrátit přesou pozici nalezené buňky?

A co konkrétně na tom nefunguje? Teď jsem to zkusil a funguje.
Jediný problém by snad mohl být v tom, že jde o maticový vzorec a ten je ve starších verzích Excelu potřeba vkládat pomocí Ctrl+Shift+Enter.

Aha, už jsem na něco přišel. Správně mi napíše první sloupec a první buňku, kde danou hodnotu našel.

Když ji ale smažu, zůstane tam stále B2.

Avšak, když smažu řádek 2, změní se to na B3.

Stejně tak se to změní na C2, pokud bych smazal B.

To ale na věci nic víceméně nemění. Nechápu, proč se to tak chová. Když smažu buňku B2, má se to okamžitě změnit na B3 a ne až po smazání všech stejných hodnot na onom řádku (sloupce to samé)

Nevíte, prosím Vás, co s tím?

PS. Nemám starý Excel, takže to není třeba vkládat jiným způsobem respektive se to chová stejně.

Ono to funguje tak, že najde první odpovídající sloupec a první odpovídající řádek a pak to spojí. Což ale dohromady nemusí dávat smysl. Jinými slovy ten vzorec nefunguje, pokud je to tam vícekrát.

OK, a víte, jak to upravit? Teoreticky bych mohl použít vícekrát ten první, ale vzhledem k tomu, že to potřebuji asi u 15 sloupců, je to na mašli.

Třeba nějak takhle:

=IFERROR(
    ADDRESS(
        MIN(IF(B2:AD100="example"; ROW(B2:AD100); 1048576));
        MIN(IF((B2:AD100="example") * (ROW(B2:AD100) = MIN(IF(B2:AD100="example"; ROW(B2:AD100); 1048576))); COLUMN(B2:AD100); 1048576));
        4
    );
    "Not found"
)

Tohle už funguje. Sice to dělá po řádcích, ale to je asi nepodstatné. Mockrát děkuji

Ak treba po stĺpcoch tak len prechoď logiku v tých 2 argumentoch.

Omlouvám se, tohle je teprve začátek. (A nechci to dávat do samostatné otázky) Původní tabulka je v tomto stylu.

Chci najít první buňku s hodnotou "example", která o řádek výše neobsahuje "OK".

Teď nemám přístup k anglické verzi, takže sorry, že je to trochu matoucí. Každopádně, tohle mně vygenerovalo chatgpt, když jsem mu poradil ten Váš kód. Bohužel doteď jsem se nedopracoval k tomu, aby to správně fungovalo. Pořád to píše Not found

=IFERROR(
    ODKAZ(
        MIN(KDYŽ((B3:AD100="*example") * (B2:AD99<>"OK"); ŘÁDEK(B3:AD100))); 
        MIN(KDYŽ((B3:AD100="*example") * (B2:AD99<>"OK") * (ŘÁDEK(B3:AD100)=MIN(KDYŽ((B3:AD100="*example") * (B2:AD99<>"OK"); ŘÁDEK(B3:AD100); 1048576))); SLOUPEC(B3:AD100); 1048576));
        4
    );
    "Not found"
)

Nevíte, jak tohle ještě upravit, prosím?

Proč tam máš ty hvězdičky?

To je jenom narychlo přepsané. V originální tabulce jsou dva různé texty, ale končí stejným slovem, proto je tam hvězdička, která v této tabulce není nutná.

=IFERROR(
    ADDRESS(
        MIN(IF((B2:AD100="example") * (OFFSET(B2:AD100; -1; 0) <> "OK"); ROW(B2:AD100); 1048576));
        MIN(IF((B2:AD100="example") * (OFFSET(B2:AD100; -1; 0) <> "OK") * (ROW(B2:AD100) = MIN(IF((B2:AD100="example") * (OFFSET(B2:AD100; -1; 0) <> "OK"); ROW(B2:AD100); 1048576))); COLUMN(B2:AD100); 1048576));
        4
    );
    "Not found"
)

Jo, tohle už je finálně to, co jsem chtěl. Děkuji

Tak možná by bylo lepší se hned na začátku zeptat, co vlastně chceš, ať se to nemusí honit přes 3 iterace.