Excel: postupné kopírování z různých listů do jednoho (makro?)

prečo pripúšťaš taký bordel v zdrojových hárkoch?
a) Prečo nemáš vo všetkých zdrojových hárkoch pevne zadanú bunku, kde začína tabuľka?
Akože... nie že by to nešlo ale zbytočne to komplikuje...
b) To na každom hárku bude iba jeden stĺpec údajov?
c) Priložený kód urobí to, čo chceš, ale ak ho pochopíš, zistíš, že aktuálne oblasti na zdrojových hárkoch musia byť súvislé.
(V Tvojom príklade síce súvislé sú, ale ako to bude v ostatných prípadoch, ktoré sa môžu vyskytnúť?)
Kód pracuje so súvislou oblasťou odvodenou od poslednej bunky.
d) Kód si zistí počet hárkov, pričom posledný považuje za sumarizačný.
e) Kód neošetruje stav, keď dodatočne pridáš ďalšie hárky (neprilepí obsah novopriloženého hárka za výsledkový zoznam).
Musel by si zmazať celý obsah výsledkového hárka a nechať prebehnúť znova
f) To, že niektorý zoznam môže byť prázdny chápem ako prázdny hárok, lebo ako vravím vyššie, kód si zisťuje poslednú vyplnenú bunku na hárku a od nej si odvodzuje oblasť pre kopírovanie...
g) Samozrejme, že keď do zošita zahrnieš makro, musíš ho uložiť vo formáte xlsm

Sub Sustredenie()
    Application.ScreenUpdating = False
    RiadokCiela = 1
    For i = 1 To ActiveWorkbook.Sheets.Count - 1
        Sheets(i).Select
        Selection.SpecialCells(xlCellTypeLastCell).Select
        Selection.CurrentRegion.Select
        PocetRiadkov = Selection.Rows.Count
        If PocetRiadkov = 1 And ActiveCell = "" Then PocetRiadkov = 0
        Selection.Copy
        Sheets(ActiveWorkbook.Sheets.Count).Select
        Range("A" & RiadokCiela).Select
        Selection.PasteSpecial Paste:=xlPasteValues
        RiadokCiela = RiadokCiela + PocetRiadkov
    Next i
    Application.CutCopyMode = False
    For i = 1 To ActiveWorkbook.Sheets.Count
        Sheets(i).Select
        Range("A1").Select
    Next i
    Application.ScreenUpdating = True
End Sub

Díky, musím to trochu upřesnit (a zdroje jsem upravil).

Na jednotlivých listech je samozřejmě mnohem více údajů, ale seznam z jednotlivých listů začíná vždy na buňce M2 (takže M2, M3,... Mx). Pod poslední položkou už nic není.

Seznam se bude vytvářet z těchto listů (pořadí je nutno dodržet).
Jejich přesné názvy jsou:

a0
a1
a2
a3
a4
a5
b1
b2
b3
c
(ty názvy už změnit nemohu, je na to navázáno spousta rozsáhlých maker)

Pokud na některém zdrojovém listu není nic v buňce M2, přeskočí se na další list. V cílovém listu začíná seznam v buňce A1.

Pokiaľ platí, že hárky sú v zošite usporiadané v tomto poradí, nie je potrebné v načítavaní hárkov nič meniť, zmením len zistenie rozsahu buniek v stĺpci M.
Kód postupne berie do radu hárky od prvého (v zošite) až po predposledný a naukladá údaje do posledného hárka.
Pokiaľ v zošite nie sú ďalšie hárky, tak nie je dôvod, prečo by to nemalo fungovať aj bez uvádzania ich mien. Alebo ich chceš načítavať podľa mien hárkov? Potom sa to totiž komplikuje a nabaľuje... treba ošetriť, či nenastane chyba (napr omylom sa v zošite nebude vyskytovať niektorý z uvedených hárkov alebo omylom bude nazvaný inak a pod...)
Mám chápať, že hárok "c" je ten výsledkový, alebo výsledkový je ešte ďalší voči uvedeným?

Riešiť budem až po odpovedi...

1. Listů je v sešitě mnohem více
2. Potřebné listy nejsou nijak seřazeny.
- můžu je seřadit, aby byly na konci, tedy nejprve řada jiných listů (nepotřebných pro výsledný seznam), pak zdrojové listy a0-c a nakonec list s výsledným seznamem.
- v každém případě budou vždy přítomny všechny uvedené ZDROJOVÉ listy a budou se jmenovat, jak jsem uvedl, tedy

a0
a1
a2
a3
a4
a5
b1
b2
b3
c

3. výsledný seznam bude v listu, který se jmenuje "KH-vysledek". Ten zařadím jako úplně poslední list sešitu.
4. Ze zdrojových stránek se bere jako první hodnota v buňce M2. V buňce nad ní, v M1, je nějaký text (nadpis), který kopírovat do seznamu nechci. V případě nutnosti mohu obsah M1 smazat. M2 ale posunout nahoru nemohu, seznam musí začínat vždy tam.

---

K té změně pořadí listů v sešitu: snad předpokládám správně, že jejich přehození nijak neovlivní vazby/vzorečky a kopírování mezi listy. kopírovací makra mám dělané vždy tak, že se jmenovitě odkazuje na konkrétní list (ne na nějaké pořadí listu v sešitu)...

ok, moment

Tu máš úplne jedno, kde sa zdrojové i cieľový hárok nachádzajú, akonáhle však dôjde kód k príkazu na odvolanie sa na neexistujúci hárok, vykonávanie bude prerušené v tom stave, k akému sa dostal, než narazil na chybu a tam dá hlášku o chybe.
Údaje v stĺpci M musia byť súvislé, inak dôjde k označeniu oblasti len po prvú prázdnu bunku.

Sub Sustredenie()
    On Error GoTo Chyba
    Harky = Array("a0", "a1", "a2", "a3", "a4", "a5", "b1", "b2", "b3", "c")
    Harok = "KH-vysledek"
    Application.ScreenUpdating = False
    Sheets(Harok).Select
    RiadokCiela = 1
    For i = 0 To 9
        Harok = Harky(i)
        Sheets(Harky(i)).Select
        If Range("M2") = "" Then GoTo Dalsi
        If Range("M3") = "" Then
            Range("M2").Select
            Else: Range("M2:M" & Range("M2").End(xlDown).Row).Select
        End If
        PocetRiadkov = Selection.Rows.Count
        Selection.Copy
        Sheets("KH-vysledek").Select
        Range("A" & RiadokCiela).Select
        Selection.PasteSpecial Paste:=xlPasteValues
        Application.CutCopyMode = False
        Sheets(Harky(i)).Select
        Range("A1").Select
        RiadokCiela = RiadokCiela + PocetRiadkov
Dalsi:
    Next i
    Sheets("KH-vysledek").Select
    Range("A1").Select
    Application.ScreenUpdating = True
    MsgBox "Zlučovanie úspešne dokončené.", vbInformation, "Hotovo"
    Exit Sub
Chyba:
    Application.ScreenUpdating = True
    If Harok = "KH-vysledek" Then GoTo EVR
    Sheets("KH-vysledek").Select
    Range("A1").Select
EVR:
    MsgBox "Hárok """ & Harok & """ neexistuje!" & Chr(13) & "Zlučovanie bolo pozastavené!", vbCritical, "Chyba"
End Sub

Funguje
Je to pěkné, když to s Excelem umíš, takové to "for 1 = 0 to 9" spolu s "if"...

Pokud bych potřeboval přidat či změnit další listy do vytvářeného seznamu (vždy se začátkem v M2), změnil bych

Harky = Array("a0", "a1", "a2", "a3", "a4", "a5", "b1", "b2", "b3", "c")

s uvedením požadovaného pořadí

a

For i = 0 To 9

podle skutečného počtu zdrojových listů, v případě 12 listů by to bylo:

For i = 0 To 11

.

Je tomu tak?

ano, ale nefunguje to pre dodatočné pridanie hárkov, aby Ti do výsledkového hárka pridalo k už existujúcemu zlúčenému zoznamu údaje dodatočne pridaného hárka.
Pokiaľ makro znova spustíš, začína to znova od začiatku (samozrejme aby vo výsledkovom hárku neostali zvyšky predchádzajúceho zlúčenia, treba stĺpec "A" výsledkového hárka pred opätovným spustením vymazať, prípadne sa to môže doplniť do makra, nech automaticky pred novým zlučovaním zmaže pôvodný výsledok...)
Tu máš aj s doplneným výmazom obsahu stĺpca "A" vo výsledkovom hárku pred vytvorením nového zlúčeného zoznamu:

Sub Sustredenie()
    On Error GoTo Chyba
    Harky = Array("a0", "a1", "a2", "a3", "a4", "a5", "b1", "b2", "b3", "c")
    Harok = "KH-vysledek"
    Application.ScreenUpdating = False
    Sheets(Harok).Select
    Columns("A:A").ClearContents
    Range("A1").Select
    RiadokCiela = 1
    For i = 0 To 9
        Harok = Harky(i)
        Sheets(Harky(i)).Select
        If Range("M2") = "" Then GoTo Dalsi
        If Range("M3") = "" Then
            Range("M2").Select
            Else: Range("M2:M" & Range("M2").End(xlDown).Row).Select
        End If
        PocetRiadkov = Selection.Rows.Count
        Selection.Copy
        Sheets("KH-vysledek").Select
        Range("A" & RiadokCiela).Select
        Selection.PasteSpecial Paste:=xlPasteValues
        Application.CutCopyMode = False
        Sheets(Harky(i)).Select
        Range("A1").Select
        RiadokCiela = RiadokCiela + PocetRiadkov
Dalsi:
    Next i
    Sheets("KH-vysledek").Select
    Range("A1").Select
    Application.ScreenUpdating = True
    MsgBox "Zlučovanie úspešne dokončené", vbInformation, "Hotovo"
    Exit Sub
Chyba:
    Application.ScreenUpdating = True
    If Harok = "KH-vysledek" Then GoTo EVR
    Sheets("KH-vysledek").Select
    Range("A1").Select
EVR:
    MsgBox "Hárok """ & Harok & """ neexistuje!" & Chr(13) & "Zlučovanie bolo pozastavené!", vbCritical, "Chyba"
End Sub