Algoritmus nebo pomoc v Excelu

Takže jednoduše řečeno, srozumitelně, potřebuješ vyselektovat ty řádky, kde je nějaký konkrétní text.

Velice jedoduché je řešení v jakémkoliv programovacím jazyku. Stačí uložit dokument, jako CSV.

Až budu mít čas, tak ti napíšu jednoduchou apku, ale možná někdo něco vytvoří přímo pro ten Excel.
Tak zatím nebudu nosit dříví do lesa.

Dobrý večer, ano přesně tak, děkuji. To by by bylo super, díky

Proc vsichni delaji v Excelu ktery uz davno nepouzivam :( Google sheets by byl asi na makro jiny.

Pokud trochu v excelu umis, tak nahraj makro kde vyberes radek a prekopirujes ho do noveho listu a pak do toho makra rucne pridas vyhledavani ktere, jak pises, mas/umis.

Google: excel copy rows with specific text

Např.
https://spreadsheetplanet.com/select-rows-with-specific-text-excel/
nebo
https://www.mrexcel.com/board/threads/copy-entire-row-if-cell-contains-specific-text-and-paste-values-into-others-worksheets.1165742/

Vyzkoušej.

Option Explicit

Sub Kopiruj_TEREZU()
Dim Oblast As Range
Dim Radek As Range
Dim Bunka As Range
Dim KopirovanaOblast As Range

Set Oblast = List1.UsedRange

For Each Radek In Oblast.Rows
    For Each Bunka In Radek.Cells
        If Bunka.Value = "Tereza" Then
            If KopirovanaOblast Is Nothing Then
                Set KopirovanaOblast = Bunka.EntireRow
                Exit For
            Else
                Set KopirovanaOblast = Union(KopirovanaOblast, Bunka.EntireRow)
                Exit For
            End If
        End If
    Next Bunka
Next Radek

If Not KopirovanaOblast Is Nothing Then
    KopirovanaOblast.Copy List2.Range("A1")
    If ActiveSheet.CodeName = "List1" Then List1.Range("A1").Select
    MsgBox "Kopírování dokončeno.", vbInformation, "Hotovo"
Else
    MsgBox "Žádná data ke kopírování.", vbExclamation, "Varování"
End If

Set Oblast = Nothing
Set KopirovanaOblast = Nothing
Set Bunka = Nothing
End Sub

Paráda, moc děkuji...
Páni, to muselo dát práce. Díky moc.

Uvažuju, jak tam ještě dostat input box se zadáním hledaného textu, když zítra bude třeba hledat Mařenu :)

Něco jako

searchString = InputBox("Zadej hledaný text")

a pak to dostat do makra místo toho

If Bunka.Value = "Tereza" Then

Jednoduxho namiesto "Tereza" napíšeš searchString, ktorý bude vopred nastavený napríklad tým InputBoxom.

Jo, to je ono.
Dovolím si tedy upravit ten Sikiho kód:

Sub Kopiruj_cokoliv()
Dim Oblast As Range
Dim Radek As Range
Dim Bunka As Range
Dim KopirovanaOblast As Range

searchString = InputBox("Zadej hledaný text")

Set Oblast = List1.UsedRange

For Each Radek In Oblast.Rows
    For Each Bunka In Radek.Cells
        If Bunka.Value = searchString Then
            If KopirovanaOblast Is Nothing Then
                Set KopirovanaOblast = Bunka.EntireRow
                Exit For
            Else
                Set KopirovanaOblast = Union(KopirovanaOblast, Bunka.EntireRow)
                Exit For
            End If
        End If
    Next Bunka
Next Radek

If Not KopirovanaOblast Is Nothing Then
    KopirovanaOblast.Copy List2.Range("A1")
    If ActiveSheet.CodeName = "List1" Then List1.Range("A1").Select
    MsgBox "Kopírování dokončeno.", vbInformation, "Hotovo"
Else
    MsgBox "Žádná data ke kopírování.", vbExclamation, "Varování"
End If

Set Oblast = Nothing
Set KopirovanaOblast = Nothing
Set Bunka = Nothing
End Sub

Doplním, že kód nefunguje na čísla (vyhledat třeba "56") ani na části textu v buňkách (nenajde "Tereza" v buňce s "Tereza Nováková"). Hledání je také case sensitive, nenajde tedy "tereza".

Aj to sa dá ľahko vyriešiť, namiesto priameho porovnania obsahu bunky sa použije funkcia INSTR, čiže nehľadá sa presná zhoda s bunkou ale len výskyt textu v bunke, napríklad aj časť slova.

https://www.automateexcel.com/vba/instr-find-text/