Delphi - TTable - filter

Na zadani filtru podle zacatku obsahu polozky by mela slouzit property FilterOptions:
TFilterOption = (foCaseInsensitive, foNoPartialCompare);
Takze pokud nic nevyplnis, nemel by byt filtr zavisly na velikosti pismen a mel by automaticky brat (i bez hvezdicky) zacatek retezce

Bez hviezdičky to berie iba položky s obsahom, ktorý sa zhoduje so zadaným textom. Vyskúšam čo píšete.

Nepozná TTable.FilterOption.

Edit: Trošku som sa s tým pohral a zistil som, že to je:
TTable.FilterOptions

Dobre mám "case sensitive", ale stále to nehľadá uprostred položky, iba od začiatku. Čo teraz? V helpe som nič na toto nenašiel. Je teda možnosť nadefinovať si vlastnú metódu na porovnávanie obsahu?

Na toto sa pouzivaju standartne "zoliky"
? - nahradny znak
* - vsetko
Ked chces najst nieco v strede napriklad '*jan*' tak najde aj 'janko' aj 'vojanko' aj 'novakjan' atd
pohraj sa s tymi zolikmi a uvidis...
este je tam volba na [foNoPartialCompare] - skus aj to...

Ale ja tam chcem partial. *jan* som skúšal. Inak by som sa to nepýtal. Hviezvička funguje ako v DOSe, čiže iba na konci. Skús.

Neviem o aku tabulku ide , /databazovy system/ ...
Ani % nefunguje?

Ak nejde priamo cez filter da sa to urobit aj cez udalost Table1
table1filterrecord(Dataset:Tdataset;Var Accept:Boolean);
begin
//Napriklad aj takto , ine si urcite domyslis...:)
accept:=pos('JAN',table1.fieldbyname ('meno').asstring)>0;
end;

Muzes si to resit sam v udalosti OnFilterRecord (aspon tak se to tusim jmenuje)

Přesně tak. Zde nabízím (moji vlastní) rutinu, na porovnání řetězce s žolíky:

{-------------------------------- Porovná masku se znaky * a ? se stringem ---------------------------------------}
function StrLike (AMaska, AString: string; const ACaseSensitive: boolean = false): boolean;
{	AMaska		:= Porovnávací maska se znaky * a ?. }
{	AString		:= String k porovnání.  }
{	ACaseSensitive	:= true - pak je citlivé k velikosti písmen, false nebo nic není citlivé na velikost písmen. }
{Vrací: true jestli je shoda, false jestli není }

var	iStringu, iMasky, iKonceStringu, iKonceMasky, i, j: integer; TempString, TempMask: string;
{------------------------------------ Aby to bylo co nejrychlejší }
{$IFOPT Q+} {$DEFINE JeOwerflowCheck} {$OVERFLOWCHECKS OFF} {$ENDIF}
{$IFOPT R+} {$DEFINE JeRangeChecks}   {$RANGECHECKS OFF}    {$ENDIF}
begin
	{------------------------------- Jestli to nemá být case sensitive, tak to převést na velký písmena }
	if not ACaseSensitive then begin AString := AnsiUppercase (AString); AMaska := AnsiUppercase (AMaska) end;

	{----------------------------------- Jedeme tak dlouho, dokud není některý řetěz vyčerpán }
	iStringu := 1; iKonceStringu := length (AString); iMasky := 1; iKonceMasky := length (AMaska);
	while (iStringu <= iKonceStringu) and (iMasky <= iKonceMasky) do begin
		{------------------------ Rozskok podle znaků masky }
		case AMaska [iMasky] of
			{-------------------- Při '?' přeskočit znak stringu i masky, protože srovnání je vždy Ok }
			'?': begin inc (iStringu); inc (iMasky) end;

			{-------------------- Při '*' přeskočit '*' a najít shodu }
			'*': begin
						inc (iMasky);
						{------------- Když maska končí *, končíme taky a je to porovnané Ok... }
						if iMasky > iKonceMasky then
							iStringu := iKonceStringu + 1
						{------------- ... jinak hledat shodu }
						else begin
							TempString	:= copy (AString, iStringu, MaxInt); TempMask := copy (AMaska, iMasky, MaxInt);
							i		:= PosChar ('*', TempMask); if i = 0 then i := MaxInt; j := PosChar ('?', TempMask);
							if (j <> 0) and (j < i) then i := j;
							TempMask	:= copy (TempMask, 1, i - 1); i := pos (TempMask, TempString); if (i = 0) and (TempMask <> '') then break;
							if i <> 0 then begin inc (iStringu, i + length (TempMask) - 1); inc (iMasky, length (TempMask)) end;
						end
					 end
		{---------------------- Cokoliv jiného se musí srovnat celé a při prvním rozdílu končíme }
		else
			if AString [iStringu] = AMaska [iMasky] then begin inc (iStringu); inc (iMasky) end else break;
		end { case }
	end; { while }

	{-------------- Ok srovnání je když se to oboje stejně vyčerpalo stejně a nebo v masce zbyla '*'}
	Result := ((iStringu > iKonceStringu) and (iMasky > iKonceMasky)) or (copy (AMaska, iMasky, MaxInt) = '*');
end;
{$IFDEF JeOwerflowCheck} {$OVERFLOWCHECKS ON} {$ENDIF}
{$IFDEF JeRangeChecks}   {$RANGECHECKS ON}    {$ENDIF}

Uvnitře je použita tato funkce (možno jí nacpat dovnitř).

{------------ Pascalské POS optimalizované pro hledání 1 znaku  ---------------------}
function PosChar (const c: char; const s: string): LongInt; register; assembler;
{	c	:= Znak co hledáme }
{	s	:= Kde to hledáme  }
{Vrací (v EAX): Pozici v s (index znaku), nenalezne-li se c v s, vrací 0 }
asm
	PUSH	EDI

	MOV	EDI, s;		{ Point EDI to s       }
	CMP	EDI, 0;
	JZ	@Kulovy;	{ Řetěz je NIL, to jest prázdný }

	MOV	AL, c;		{ AL znak co hledáme   }
	MOV	ECX, -4 (EDI);	{ Délka řetězu do ECX }
	MOV	EDX, EDI;	{ Úschova ad. začátku řetězu }

	CLD;			{ SCASB pojede nahoru }
	REPNE	SCASB;
	JNE	@Kulovy;	{ Nenašlo se to }

	MOV	EAX, EDI;	{ EAX kde to skončilo + 1 }
	SUB	EAX, EDX;	{ EAX je pozice v řetězu }
	JMP	@Finish;

@Kulovy:XOR	EAX, EAX;	{ EAX := 0 --> že se našlo prd }

@Finish:POP	EDI;
end;

Nezkousel jsi pouzit funkci MatchesMask() z unity Masks ?

To moje je podstatně rychlejší.

Mas pravdu, je to asi 4x rychlejsi. Na 100000 porovnani tva pulsekunda oproti 2s funkce MatchesMasks()

Já to právě třeba používám v OnFiltered. Mám ve vyhledávacích oknech (třeba adresářů) takovou funkci, že píšeš do políčka a ono to vyhledá text ať je v kterémkoliv sloupečku a kdekoliv. Filtruje to současně za psaní. Třeba víš kus jména firmy, ulici a nevíš přesně jak to v tom adresáři je. Pak se musí tato funkce použít v OnFiltered na všechny sloupce tabulky krát počet řádků. Tam je pak to pak každá instrukce navíc znát (aby to při pasní nezadrhávalo a plynule filtrovalo). Samozřejmě, když to použiješ v programu "jen občas", tak je to putna, jak je to rychlé.
//Edit: BTW tu funkci jsem dělal v době kamenné Delphi, kdy tam ještě nebyla od přírody.

Áno, áno, presne to robím aj ja.

Edit: Tú procedúru teda len zaradím k udalosti OnFilterRecord?

Nechceš poslat někam celý program s tou tabulkou, jak to řeším já?

Ja žew som ťa nahneval som si myslel v prvej chvíli. Môžeš a pozriem saa naň.. Ďakujem. Myslím, že to asi odfajknem teda.

Proč bych se měl hněvat?
Zde máš inspiraci: HF.zip

Veľmi pekne ďakujem.

Tento havo vyzerá zo všetkých najlepšie navrhujem ponechať. A keď nie, tak mám lepší nápad: Vložiť do PSPadu ako pomocníka (niečo ako Spinka v Office) A to som teraz myslel vážne. Ten havo by sa pekne hodil do PSPadu.

Nechni ani domejšlet, co to má za vobláček na vocáskem...

Aspoň vieme, že je načase vyvetrať.

@Kulovy:XOR	EAX, EAX;	{ EAX := 0 --> že se našlo prd }

Škoda, že niečo takéto sa nedá nájsť v resource. To by bolo dobré. Spomenul som si, ako raz dávali v telke dokument, kde ukazovali chlapíkov, ktorí nerobili nič iné, len rozoberali čipy a hľadali na nich kresby. V čipe kalkulačky bol nakreslený nejaký mimozemšťan a podobne.

Kdybys viděl moje komentáře k assemblerským programům pro sálové počítače (tam je třeba komentovat skoro každou instrukci, nebo se v tom nikdo za měsíc už nevyzná - třeba kompilátor Cobolu měl cca 80 000 řádek)... Když jsem odcházel na vlastní nohu, tak při předávce se místo kontroly všichni nezřízeně chechtali...

Aspoň je človeku pri tom veselo, keď niečo programuje. Kamoš mi dal zdroják na dokončenie v Delphi. Až po čase som si všimol, že tam popisoval výpočet súradníc TImage a na konci toho komentáru napísal: prije*aná matematika. Skoro som pustil od smiechu. Bolo to samozrejme bez hviezdičky.

Kdybys videl moje promenne radsi nekomentovat.